FPC New Features Trunk

About this page

Below you can find a list of new features introduced since the previous release, along with some background information and examples. Note that since svn trunk is by definition still under development, some of the features here may still change before they end up in a release version.

A list of changes that may break existing code can be found here.

All systems

Compiler

fpcres can compile RC files

• Overview: The fpcres utility gained support for compiling RC files to RES files if the output format (parameter -of) is set to rc. The Free Pascal compiler itself can use fpcres instead of windres or gorc as well if the option -FF is supplied.
• Notes: Using fpcres instead of windres or gorc will become default once a release with the new fpcres is released.
• svn: 46398 (and others before and after that)

Language

Support for "volatile" intrinsic

• Overview: A volatile intrinsic has been added to indicate to the code generator that a particular load from or store to a memory location must not be removed.
• Notes:
  • Delphi uses an attribute rather than an intrinsic. Such support will be added once support for attributes is available in FPC. An intrinsic that applies only to a specific memory access also has the advantages outlined in https://lwn.net/Articles/233482/
  • Accesses to fixed absolute addresses (as common on DOS and embedded platforms) are automatically marked as volatile by the compiler.
• Example: https://gitlab.com/freepascal.org/fpc/source/-/blob/main/tests/test/tmt1.pp
• svn: 40465

Support for "noinline" modifier

• Overview: A noinline modifier has been added that can be used to prevent a routine from ever being inlined (even by automatic inlining).
• Notes: Mainly added for internal compiler usage related to LLVM support.
• svn: 41198

Support for multiple active helpers per type

• Overview: With the modeswitch multihelpers multiple helpers for a single type can be active at once. If a member of the type is accessed it's first checked in all helpers that are in scope in reverse order before the extended type itself is checked.
• Examples: All tests with the name tmshlp*.pp in https://gitlab.com/freepascal.org/fpc/source/-/tree/main/tests/test
• svn: 42026

Support for custom attributes

• Overview: Custom attributes allow to decorate types and published properties of classes to be decorated with additional metadata. The metadata are by itself descendants of TCustomAttribute and can take additional parameters if the classes have a suitable constructor to take these parameters. This feature requires the new modeswitch PrefixedAttributes. This modeswitch is active by default in modes Delphi and DelphiUnicode. Attributes can be queried using the TypInfo or Rtti units.
• Notes: More information can be seen in the announcement mail and Custom Attributes
• svn: 42356 - 42411
• Example:

program tcustomattr;

{$mode objfpc}{$H+}
{$modeswitch prefixedattributes}

type
  TMyAttribute = class(TCustomAttribute)
    constructor Create;
    constructor Create(aArg: String);
    constructor Create(aArg: TGUID);
    constructor Create(aArg: LongInt);
  end;

  {$M+}
  [TMyAttribute]
  TTestClass = class
  private
    fTest: LongInt;
  published
    [TMyAttribute('Test')]
    property Test: LongInt read fTest;
  end;
  {$M-}

  [TMyAttribute(1234)]
  [TMy('Hello World')]
  TTestEnum = (
    teOne,
    teTwo
  );

  [TMyAttribute(IInterface), TMy(42)]
  TLongInt = type LongInt;

constructor TMyAttribute.Create;
begin
end;

constructor TMyAttribute.Create(aArg: String);
begin
end;

constructor TMyAttribute.Create(aArg: LongInt);
begin
end;

constructor TMyAttribute.Create(aArg: TGUID);
begin
end;

begin

end.

Support for constant parameters in generics

• Overview: Generic types and routines can now be declared with constants as parameters which function as untyped constants inside the generic. However these generic parameters have a type which allows the author of the generic to restrict the possible values for the constant. Only constant types that can also be used for untyped constants can be used.
• Notes:
  • This feature is not Delphi compatible, but can be used in mode Delphi as well
  • More information is available in the announcement mail.
• Examples: All tests with the name tgenconst*.pp in https://gitlab.com/freepascal.org/fpc/source/-/tree/main/tests/test
• svn: 45080

Support for "IsConstValue" intrinsic

• Overview: An IsConstValue intrinsic has been added to check whether a provided value is considered a constant value. This is mainly useful inside inlined functions to manually improve the generated code if a constant is encountered.
• Notes:
  • This function returns a constant Boolean value and is Delphi compatible.
  • Typed constants are not considered constants (Delphi compatible and also compatible with the usual modus operandi regarding typed constants).
• Example: https://gitlab.com/freepascal.org/fpc/source/-/tree/main/tests/test/tisconstvalue2.pp
• svn: 45695

Copy supports Open Array parameters

• Overview: The Copy intrinsic can now be used to copy (a part of) the contents of an open array parameter to a dynamic array.
• Notes:
  • The result of the Copy function will have the type of a dynamic array with the same element type as the parameter that is copied from.
  • If the Start parameter is out of range the resulting dynamic array will be empty.
  • If the Count parameter is too large then the resulting dynamic array will only contain the elements that exist.
• svn: 46890
• Example:

procedure Test(aArg: array of LongInt);
var
  arr: array of LongInt;
begin
  arr := Copy(aArg, 3, 5);
end;

Array constructors for static arrays

• Overview: Array constructors can be used to assign values to static arrays.
• Notes:
  • The array constructor needs to have the same amount of elements as the static array.
  • The first element of the array constructor will be placed at the location of the first element of the static array (e.g. if the array starts at -1 the first element will be at that location).
  • Arrays with enumeration index are supported as well.
• svn: 46891, 46901
• Example: https://gitlab.com/freepascal.org/fpc/source/-/tree/main/tests/test/tarrconstr16.pp

"Align" modifier support for record definitions

• Overview: It is now possible to add an Align X modifier at the end of a record definition to indicate that the record as a whole should be aligned to a particular boundary.
• Notes:
  • Should be Delphi compatible, although documentation is not available ("semi-official" reference; the mentioned issue does not exist in the FPC implementation).
  • This does not influence the alignment of the individual fields, which are still aligned according to the current {$packrecords y}/{$align y} settings.
  • X can be 1, 2, 4, 8, 16, 32 or 64.
• svn: 47892
• Example: https://gitlab.com/freepascal.org/fpc/source/-/blob/main/tests/webtbs/tw28927.pp

Support for binary literals in Delphi mode

• Overview: It is now possible to use binary literals ('%' as prefix) in Delphi mode.
• Notes: Delphi compatibility.
• GitLab issue: #39503
• Example:

{$mode Delphi}
var
  b: byte;
begin
  b:=%11001001;
end.

Support for Digit Separator

• Overview: It is now possible to use the Digit Separator ('_') with the underscoreisseparator modeswitch. It is also enabled by default in Delphi mode.
• Notes: Delphi compatibility.
• GitLab issue: #39504
• Example:

{$mode Delphi}
var
  i: Integer;
  r: Real;
begin
  i := %1001_1001;
  i := &121_102;
  i := 1_123_123;
  i := $1_123_123;  
  r := 1_123_123.000_000;
  r := 1_123_123.000_000e1_2;
end.

Support for forward declarations of generic types

• Overview: It is now possible to use forward declarations for generic classes and interfaces like is possible for non-generic classes and interfaces.
• Notes:
  • Generic type constraints and const declarations need to be used for both the forward and the final implementation like is necessary for global generic routines.
  • This is Delphi-compatible.
• Commit: 2a502350
• Example:

{$mode objfpc}
type
  generic TTest<T> = class;
  generic TFoo<T: class> = class;
  generic TBar<const N: LongInt> = class;

  TSomething = class
    fTest: specialize TTest<LongInt>;
    fFoo: specialize TFoo<TObject>;
    fBar: specialize TBar<42>;
  end;

  generic TTest<T> = class end;
  generic TFoo<T: class> = class end;
  generic TBar<const N: LongInt> = class end;

begin
end.

Support for Function References and Anonymous Functions

• Function References: Function References (also applicable names are Procedure References and Routine References, in the following only Function References will be used) are types that can take a function (or procedure or routine), method, function variable (or procedure variable or routine variable), method variable, nested function (or nested procedure or nested routine) or an anonymous function (or anonymous procedure or anonymous routine) as a value. The function reference can then be used to call the provided function just like other similar routine pointer types. In contrast to these other types nearly all function-like constructs can be assigned to it (the only exception are nested function variables (or nested procedure variables or nested routine variables), more about that later on) and then used or stored.
• Anonymous Functions: Anonymous Functions (or Anonymous Procedures or Anonymous Routines, in the following simply Anonymous Functions) are routines that have no name associated with them and are declared in the middle of a code block (for example on the right side of an expression or as a parameter for a function call). However they can just as well be called directly like a nested function (or nested procedure or nested routine) would.
• More Information and Examples: Feature announcement: Function References and Anonymous Functions
• GitLab Issue: #24481

Descendant type helpers can extend type aliases

• Overview: A type helper that descends from another type helper can now extend a unique type alias of the type the inherited type helper extends. This way a type helper for the original type can be made available for the type alias as well.
• Notes:
  • The type alias the descendant extends does not need to be a direct type alias of the parent's extended type.
  • The other way around is not allowed: a type helper that inherits from another helper which extends a unique type alias can not extend the base type.
• Example: See the test for the feature.
• Commit: 7133ad7e

Support for Unicode RTL

• Overview: The Unicode RTL is required for Delphi 2009+ compatibility. This also includes support for dotted filenames like System.SysUtils
• Notes: FPC Unicode RTL.
• fpc-devel Mailinglist announcement: Unicode RTL

Support for Extended RTTI

• Overview: Extended RTTI includes the for $RTTI directive, generating RTTI metadata for all fields, methods and properties and allowing the access of the RTTI metadata via TypInfo and RTTI unit.
• Notes: Delphi 2010+ compatibility.
• GitLab issue: #38964
• Commit: 7eea8507..a9846283

Units

DaemonApp

Additional control codes on Windows

• Overview: Windows allows a service to request additional control codes to be received. For example if the session of the user changed. These might also carry additional parameters that need to be passed along to the TDaemon instance. For this the WinBindings class of the TDaemonDef now has an additional AcceptedCodes field (which is a set) that allows to define which additional codes should be requested. Then the daemon should handle the OnControlCodeEvent event handler which in contrast to the existing OnControlCode handler takes two additional parameters that carry the parameters that the function described for MSDNs LPHANDLER_FUNCTION_EX takes as well.
• Notes: This lead to slight incompatibilities which are mentioned in User Changes Trunk
• svn: 46326, 46327

Classes

Naming of Threads

• Overview: TThread.NameThreadForDebugging has been implemented for macOS.
• Notes: Delphi compatible, was already implemented for Windows, Linux and Android and finally for macOS now. Read documentation as every platform has its own restrictions.
• svn: 49323

Objects

TRawByteStringCollection

• Overview: A new object type TRawByteStringCollection, similar to TStringCollection, but works with RawByteString/AnsiString
• git: 0b8a0fb4

TUnicodeStringCollection

• Overview: A new object type TUnicodeStringCollection, similar to TStringCollection, but works with UnicodeString
• git: 0b8a0fb4

TStream methods for reading and writing RawByteString and UnicodeString

• Overview: New methods have been added to TStream for reading and writing RawByteString/AnsiString and UnicodeString types.
• Notes: The following methods have been added:

FUNCTION TStream.ReadRawByteString: RawByteString;
FUNCTION TStream.ReadUnicodeString: UnicodeString;
PROCEDURE TStream.WriteRawByteString (Const S: RawByteString);
PROCEDURE TStream.WriteUnicodeString (Const S: UnicodeString);

RawByteStrings are written to the stream as a 16-bit code page, followed by 32-bit length, followed by the string contents. UnicodeStrings are written as a 32-bit length (the number of 16-bit UTF-16 code units needed to encode the string), followed by the string itself in UTF-16.

• git: 0b8a0fb4

Free Vision

Unicode support

• Overview: Unicode versions of the Free Vision units have been added.
• Notes: The Unicode versions of the units have the same name as their non-Unicode counterparts, but with an added 'U' prefix in the beginning of their name. For example, the Unicode version of the 'app' unit is 'uapp', the Unicode version of 'views' is 'uviews', etc. The Unicode versions of the units use the UnicodeString type, instead of shortstrings and pchars. Mixing Unicode and non-Unicode Free Vision units in the same program is not supported and will not work.
• More information: Free_Vision#Unicode_version
• git: 0b8a0fb4

Video

Unicode output support

• Overview: Unicode video buffer support has been added to the Video unit.
• Notes: To use the Unicode video buffer, you must call InitEnhancedVideo instead of InitVideo and finalize the unit with DoneEnhancedVideo instead of DoneVideo. After initializing with InitEnhancedVideo, you must use the EnhancedVideoBuf array instead of VideoBuf. On non-Unicode operating systems, the Video unit will automatically translate Unicode characters to the console code page. This is done transparently to the user application, so new programs can always use EnhancedVideoBuf, without worrying about compatibility.
• git: 0b8a0fb4

Keyboard

Unicode keyboard input support

• Overview: Unicode keyboard input support has been added to the Keyboard unit.
• Notes: After initializing the unit normally via InitKeyboard, you can obtain enhanced key events, which include Unicode character information, as well as an enhanced shift state. To get enhanced key events, use GetEnhancedKeyEvent or PollEnhancedKeyEvent. They return a TEnhancedKeyEvent, which is a record with these fields:

 TEnhancedKeyEvent = record
   VirtualKeyCode: Word;    { device-independent identifier of the key }
   VirtualScanCode: Word;   { device-dependent value, generated by the keyboard }
   UnicodeChar: WideChar;   { the translated Unicode character }
   AsciiChar: Char;         { the translated ASCII character }
   ShiftState: TEnhancedShiftState;
   Flags: Byte;
 end;

TEnhancedShiftState is a set of TEnhancedShiftStateElement, which is defined as:

 TEnhancedShiftStateElement = (
   essShift,             { either Left or Right Shift is pressed }
   essLeftShift,
   essRightShift,
   essCtrl,              { either Left or Right Ctrl is pressed }
   essLeftCtrl,
   essRightCtrl,
   essAlt,               { either Left or Right Alt is pressed, but *not* AltGr }
   essLeftAlt,
   essRightAlt,          { only on keyboard layouts, without AltGr }
   essAltGr,             { only on keyboard layouts, with AltGr instead of Right Alt }
   essCapsLockPressed,
   essCapsLockOn,
   essNumLockPressed,
   essNumLockOn,
   essScrollLockPressed,
   essScrollLockOn
 );

A special value NilEnhancedKeyEvent is used to indicate no key event available in the result of PollEnhancedKeyEvent:

 { The Nil value for the enhanced key event }
 NilEnhancedKeyEvent: TEnhancedKeyEvent = (
   VirtualKeyCode: 0;
   VirtualScanCode: 0;
   UnicodeChar: #0;
   AsciiChar: #0;
   ShiftState: [];
   Flags: 0;
 );

• git: 0b8a0fb4

Darwin/macOS platforms

Support for symbolicating Dwarf backtraces

• Overview: The -gl option now works with DWARF debug information on Darwin. This is the default for non-PowerPC Darwin targets, and the only support format for ARM and 64 bit Darwin targets.
• Notes: You have to also use the -Xg command line option when compiling the main program or library, to generate a .dSYM bundle that contains all debug information. You can also do this manually by calling dsymutil
• svn: 49140

New compiler targets

Support for code generation through LLVM

• Overview: The compiler now has a code generator that generates LLVM bitcode.
• Notes: LLVM still requires target-specific support and modifications in the compiler. Initially, the LLVM code generator only works when targeting Darwin/x86-64, Darwin/AArch64 (only macOS; iOS has not been tested), Linux/x86-64, Linux/ARMHF and Linux/AArch64.
• More information: LLVM
• svn: 42260

Support for address sanitizer (asan) through LLVM

• Overview: The compiler allows to check code with the LLVM address sanitizer.
• Notes: The LLVM address sanitizer is supported for all 64 bit targets supported by the LLVM code generator.
• More information:
  • LLVM
  • Address Sanitizer on Wikipedia
• git: 403292a1

Support for the Z80

• Overview: Support has been added for generating Z80 code.
• More information: Z80

Support for the WebAssembly target

• Overview: Support has been added for generating WebAssembly code.
• More information: WebAssembly/Compiler

Support for the PlayStation 1

• Overview: Support has been added for generating programs for the Sony PlayStation 1 video game console.
• More information: PlayStation_1