CalLite: Usage/fi

From Lazarus wiki
Jump to navigationJump to search

│ English (en) │ suomi (fi) │ русский (ru) │

CalLite

Käyttö

Yksinkertaisesti pudota TCalendarLite-komponentti lomakkeelle ja näin saadaan toiminnallinen kuukausikalenteri.

Värien vaihtaminen

Kalenterin ominaisuus Colors Kerää kaikki asetukset, jotka vaikuttavat eri kohteisiin käytettäviin väreihin:

  • ArrowBorderColor: Kalenterin yläpuolella olevien nuolten reunan väri (oletus: clSilver)
  • ArrowColor: Kalenterin yläpuolella olevien nuolien täyttöväri (oletus: clSilver)
  • BackgroundColor: Koko kalenterin taustaväri (oletus: clWhite)
  • BorderColor: Valinnaisen reunuksen väri kalenterin ympärillä (oletus: clSilver). Lisäämällä kalentarin Options ominaisuuden coShowBorder arvo true:ksi niin näytetään reunus.
  • DayLineColor: Valinnaisen erotuslinjan väri ylimmän navigointiruudun ja kalenterin päiväalueen välillä (oletus: clSilver). Lisää kalenterin Options kohdasta coDayLine päälle jos halutaan näyttää tämä rivi
  • HolidayColor: Tekstin väri, jota käytetään lomapäivien esittämiseen (oletus: clRed). Lisää tapahtumakäsittelijä kohteeseen OnGetHolidays määrittelemään, mitkä päivät ovat lomapäiviä.
  • PastMonthColor: Tekstin väri, jolla näytetään edellisen tai seuraavan kuukauden päivät (oletus: clSilver).
  • SelectedDateColor: Valitun päivän täyttöväri (oletus: clMoneyGreen)
  • TextColor: Tavallisien kalenteripäivien tekstin väri (oletus: clBlack)
  • TodayFrameColor: Väri, jota käytetään suorakulman viivan värinä tämän päivän päivämäärän ympärille (oletus: clLime)
  • TopRowColor: Yläriville käytettävä taustaväri (oletus: clHighlight)
  • TopRowTextColor: Tekstin väri, jota käytetään ylärivillä (oletus: clHighlightText)
  • WeekendColor: Tekstin väri, jota käytetään esittämään viikonlopun päiviä (default: clRed)

Kalenterin erilaisten asetusten (Options) käyttö

Kalenterin näyttöä voidaan muuttaa muuttamalla kalenterin erilaisia asetuksia (Options): 

type
  TCalOption = (coBoldDayNames, coBoldHolidays, coBoldToday, coBoldTopRow,
                coBoldWeekend, coDayLine, coShowBorder, coShowHolidays,
                coShowTodayFrame, coShowTodayName, coShowTodayRow,
                coShowWeekend, coUseTopRowColors);
  • coBoldDayNames: Päivien nimet näytetään käyttäen niiden nimissä lihavoituja (bold) kirjaimia
  • coBoldHolidays: Lomapäivät näytetään käyttäen lihavoituja (bold) kirjaimia. Lomapäiviä ei normaalisti näytetä, mutta lisäämällä tapahtumakäsittelijä OnGetHolidays voidaan määritellä lomapäivät.
  • coBoldToday: Tämän päivän päivämäärän näytetään käyttäen lihavoituja (bold) kirjaimia
  • coBoldTopRow: Kuukauden nimi ja vuosi näytetään käyttäen lihavoituja (bold) kirjaimia
  • coBoldWeekend: Viikonlopun päivät näytetään käyttäen lihavoituja (bold) kirjaimia
  • coDayLine: Lisätään erotuslinja ylimmän navigointiruudun ja kalenterin päiväalueen välille
  • coShowBorder: Näytetään suorakulmainen kehys kalenterin ympärillä
  • coShowHolidays: Aktivoi korostamaan lomapäivät. Huomaa että täytyy olla myös ohjelmoitu tapahtumankäsittelijä OnGetHolidays joka määrittää lomapäivät.
  • coShowTodayFrame: Näytetään suorakulmainen kehys tämän päivän päivämäärän ympärillä
  • coShowTodayName: Lisää päivän nimen riville, joka näyttää tämän päivän päivämäärän (katso myös: coShowTodayRow)
  • coShowTodayRow: Näyttää kalenterin alareunassa olevan rivin joka näyttää tämän päivän päivämäärän (katso myös: coShowTodayName).
  • coShowWeekend: Korostaa viikonlopun päivät (katso myös: Colors.WeekendColor).
  • coUseTopRowColors: Maalaa yläreunan rivin taustat ja tekstit väreillä Colors.TopRowColor ja Colors.TopRowTextColor

Kielen vaihtaminen

Komponentin käyttämät merkkijonot voidaan helposti muuntaa eri kielille muuttamalla ominaisuuden Languages arvoa: 

type
  TLanguage = (lgEnglish, lgFrench, lgGerman, lgHebrew, lgSpanish, lgItalian,
               lgPolish, lgFinnish);

Tapahtumat

Tavallisten tapahtumien lisäksi TCalendarLite käynnistää seuraavat tapahtumat. Jotkin tapahtumat saavat sillä hetkellä valittujen solujen vuosi, kuukausi ja päivämäärät parametriksi. Joukko tilalippuja ilmoittaa, onko tämä päivä valittu vai kuuluuko edelliseen tai seuraavaan kuukauteen: 

type
  TCalCellState = (csSelectedDay, csToday, csOtherMonth);
  TCalCellStates = set of TCalCellState;
  • OnDateChange: Käynnistyy kun kalenterissa valitaan toinen päivämäärä.
  • OnDrawCell: Tällä voidaan ohittaa vakio päivän solun maalausprosessi kokonaan tai osittain. Jos Boolean parametri AContinueDrawing on asetettu oikeaksi, normaali maalausprosessi jatkuu tästä tapahtumasta poistuttaessa; jos se on false niin jätetään oletusprosessi tekemättä kyseiselle päivälle. Tapahtumaa voidaan käyttää esimerkiksi lisäämään syntymäpäivä- tai lomakuvakkeita päiväkohtaisiin soluihin.
  • OnGetDayText: Voidaan käyttää muokataksesi tekstinäyttöä määritetylle päivälle. Oletus on merkkijono, joka näyttää päiväarvon. Tämän tapahtuman avulla lomien nimet voidaan lisätä esimerkiksi kalenteriin.
  • OnGetHolidays: Määrittää, mitkä päivät kuluvan kuukauden aikana ovat vapaapäiviä. Juhlapäivien päivämäärät koodataan asetetuiksi biteiksi 32-bittisessä kokonaisluvussa.
  • OnHint: Määrittää vihjeen, joka voidaan näyttää ponnahdusikkunassa kyseisenä päivänä. Voidaan hyödyntää esimerkiksi näyttää lomapäivien nimi, jos hiiri "lepää" lomapäivän kohdalla.
  • OnMonthChange: Käynnistyy aina kun uusi kuukausi näkyy kalenterissa. Voidaan käyttää tehokkaampaan lomapäivien laskentaan.
  • OnPrepareCanvas: Tapahtuu välittömästi ennen kuin solu on maalataan. Voidaan käyttää esimerkiksi Brush- ja Pen-ominaisuuksien ohittamiseen erilaisten taustojen tekemiseksi nimeämisiin ja tärkeisiin tapahtumiin.

Lomapäivien määrittäminen

Kalenteri ei "tiedä" mitään lomapäivistä. Joten täytyy kirjoittaa tapahtumakäsittelijä määrittelemään, mitkä päivät ovat kuluvan kuukauden aikana lomapäiviä. Kuluvan kuukauden kuukausi ja vuosi-arvot välitetään parametreina. Tiedot siitä, että päivä on lomapäivä tai ei, on koodattu bittijoukoksi 32-bittisessä kokonaisluvussa. Käännösyksikkö callite yksinkertaistaa tätä tarjoamalla seuraavat yleisluonteiset aliohjelmat:

  • procedure AddHoliday(ADay: Integer; var AHolidays: THolidays): Lisää määritetyn päivän holiday bitti listaan parameterissä AHolidays.
  • function IsHoliday(ADay: Integer; AHolidays: THolidays): Boolean: Tarkistaa onko kyseinen päivä listattu parametrissä AHolidays
  • ClearHolidays(var AHolidays: THolidays): Tyhjentää holiday listan

Tässä on yksinkertainen esimerkki uudenvuoden, joulun, pääsiäisen ja whit sunnuntain lomapäivien määrittelemisestä: 

function Easter(year:integer): TDateTime; 
var
  Day, Month    : integer;
  a,b,c,d,e,m,n : integer;
begin
  case Year div 100 of
    17    : begin m := 23; n := 3; end;
    18    : begin m := 23; n := 4; end;
    19,20 : begin m := 24; n := 5; end;
    21    : begin m := 24; n := 6; end;
    else    raise Exception.Create('Only years after 1700 supported.');
  end;
  a := Year mod 19;
  b := Year mod 4;
  c := Year mod 7;
  d := (19*a + m) mod 30;
  e := (2*b + 4*c + 6*d + n) mod 7;
  day := 22 + d + e;
  Month := 3;
  if Day>31 then begin
    Day := d + e - 9;
    Month := 4;
    if (d=28) and (e=6) and (a>10) then begin
      if day=26 then day := 19;
      if day=25 then day := 18;
    end;
  end;
  result := EncodeDate(year, month, day);
end;

procedure TForm1.CalendarLite1GetHolidays(Sender: TObject; AMonth, AYear: Integer;
  var Holidays: THolidays);
var
  d, m, y: Word;
  e: TDate;
begin
  ClearHolidays(Holidays);
  if not FNoHolidays then
  begin
    // Fixed holidays
    case AMonth of
      1: AddHoliday(1, Holidays);          // Uusi vuosi
     12: AddHoliday(25, Holidays);         // Joulupäivä
    end;
    // Pääsiäinen
    e := Easter(AYear);
    DecodeDate(e, y,m,d);
    if m = AMonth then
      AddHoliday(d, Holidays);
    // Helluntai --> 49 päivää pääsiäisen jälkeen
    DecodeDate(e+49, y,m,d);
    if m = AMonth then
      AddHoliday(d, Holidays);
  end;
end;

Varmista, että kalenterissa on valittu vaihtoehto coShowHolidays, jonka avulla voit korostaa kalenterin lomapäiviä.


Lomapäivien näyttö vihjeenä

Jos halutaan näyttää lomapäivän nimi hint- ponnahdusikkunana kun hiiri "lepää" päivän päällä niin asetetaan kalenterin ShowHint arvoon true ja lisätään tapahtumakäsittelijä OnHint: 

procedure TForm1.CalendarLite1Hint(Sender: TObject; AYear, AMonth, ADay: Word;
  var AText: String);
var
  dt, e: TDate;
begin
  AText := '';
  case AMonth of
    1: if ADay = 1 then AText := 'New Year'; // Uusi vuosi
   12: if ADay = 25 then AText := 'Christmas';// Joulupäivä
   else
       e := Easter(AYear);
       dt := EncodeDate(AYear, AMonth, ADay);
       if (dt = e) then
         AText := 'Easter'    // Pääsiäinen
       else if (dt = e + 49) then
         AText := 'Whit Sunday'; // Helluntai
  end;
end;

Lomapäivien nimet kalenteriristikkoon

Voidaan myös lisätä lomapäivien nimet suoraan kalenteriristikkoon. Lisäämällä OnGetDayText tapahtumakäsittelijä. On huomattava, että kalenterin koon on oltava riittävän suuri, jotta lisätilaa voidaan käyttää tekstille: 

procedure TForm1.CalendarLite1GetDayText(Sender: TObject; AYear, AMonth, ADay: Word;
  var AText: String);
var
  s: String;
begin
  GetHintText(Sender, AYear, AMonth, ADay, s);
  if s <> '' then
    AText := IntToStr(ADay) + LineEnding + s;
end;

Lomapäivät ponnahdusvalikossa

Jos kalenterin PopupMenu ominaisuus on tyhjä, siinä on sisäänrakennettu ponnahdusvalikko, joka näyttää kaikki valitun vuoden lomia. Kuten tavallista, tämä ponnahdusikkuna avautuu klikkaamalla sitä hiiren kakkospainikkeella komponenttia.

Kuvakkeet tietyille päiville

Seuraavassa esimerkissä kuvataan syntymäpäiväkuvake kunkin vuoden marraskuun 11. päivän soluun. Kuvake tallennetaan kuvaluetteloon (TImageList) indeksissä 0: 

procedure TForm1.CalendarLite1DrawCell(Sender: TObject; ACanvas: TCanvas;
  AYear,AMonth,ADay: Word; AState: TCalCellStates; var ARect: TRect;
  var AContinueDrawing: Boolean);
var
  bmp: TBitmap;
begin
  if (AMonth = 11) and (ADay = 11) and not (csOtherMonth in AState) then begin
    bmp := TBitmap.Create;
    try
      ImageList1.GetBitmap(0, bmp);
      ACanvas.Draw(ARect.Left, (ARect.Top + ARect.Bottom - bmp.Height) div 2, bmp);
      inc(ARect.Left, bmp.Width + 2);
      // Not changing AContinueDrawing from its default value (true) means
      // that the day text is drawn by the built-in procedure into the reduced rectangle
    finally
      bmp.Free;
    end;
  end;
end;

Monivalinta

Jos ominaisuus MultiSelect on asetettu true kalenteriin voidaan valita useita päiviä. Kaikki valitut päivät piirretään korostetulla taustalla. Monivalinta ohjataan pitämällä erikoisnäppäimiä alhaalla, kun valitset päivän joko hiiren klikkauksella tai näppäimen painalluksella:

  • CTRL: Jos painetaan CTRL-näppäintä niin kun valitaan toinen päivä niin päiväys lisätään valintaan. Tällä tavoin voidaan valita päivämäärät, jotka eivät ole vierekkäisiä.
  • SHIFT: Jos ⇧ Shift-näppäintä pidetään alhaalla päivänvalinnan aikana niin valintaan lisätään kaikki päivät aikaisemmin valitun ja nykyisen päivän välillä.
  • Kaksoisklikkaus: Työpäivän kaksoisklikkaus valitsee kaikki työpäivät samalla viikolla. Painamalla CTRL- tai ⇧ Shift-näppäintä alhaalla valita laajenee yhden tai useamman viikon työpäivien valinnaksi.
  • Valintaa voidaan laajentaa naapurikuukausiksi, jos näppäimistön nuolinäppäimiä painetaan CTRL-näppäimen ollessa alhaalla.
  • Valinta poistetaan, jos jokin päivämäärä on valittu ilman, että painat mitään näistä näppäimistä tai jos yläpalkin nuolia tai pudotusvalikkoja käytetään.
  • Jos aiemmin valitut päivät lisätään toisen kerran, niin ne poistetaan valituista.
Retrieved from "https://wiki.freepascal.org/index.php?title=CalLite:_Usage/fi&oldid=128007"